build.gradle

buildscript {
    ext.compilerVersion = '1.1.50-eap-18'
    ext.librariesVersion = '1.1.50-eap-18'
    ext.eapChannel = 'https://dl.bintray.com/kotlin/kotlin-eap-1.1'
    ext.serializationRepo = 'https://kotlin.bintray.com/kotlinx'
    ext.serializationPluginVersion = '0.1'

    repositories {
        jcenter()
        maven { url serializationRepo }
        maven { url eapChannel }
        mavenLocal()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$compilerVersion"
        classpath "org.jetbrains.kotlinx:kotlin-serialization:$serializationPluginVersion"

        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.2'

        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
    }
}

ext {
    libraries = [
            kotlin_stdlib: "org.jetbrains.kotlin:kotlin-stdlib:$librariesVersion",
            kotlin_stdlib_common: "org.jetbrains.kotlin:kotlin-stdlib-common:$librariesVersion",
            kotlin_stdlib_js: "org.jetbrains.kotlin:kotlin-stdlib-js:$librariesVersion",
            kotlin_test: "org.jetbrains.kotlin:kotlin-test:$librariesVersion",
            kotlin_test_common: "org.jetbrains.kotlin:kotlin-test-common:$librariesVersion",
            kotlin_test_js: "org.jetbrains.kotlin:kotlin-test-js:$librariesVersion",
            kotlin_reflect: "org.jetbrains.kotlin:kotlin-reflect:$librariesVersion",
    ]
}

allprojects {
    group 'org.jetbrains.kotlinx'
    version '0.1'
}

apply plugin: 'kotlin'

configure([project(':jvm'), project(':js')]) {
    apply plugin: 'kotlin-serialization'

    apply plugin: 'maven-publish'
    apply plugin: 'com.jfrog.bintray'

    def varintName = "${rootProject.name}-${project.name}"

    task sourceJar(type: Jar, dependsOn: classes) {
        classifier 'sources'
        from sourceSets.main.allSource
    }

    tasks.withType(Jar) {
        archivesBaseName = varintName
    }

    publishing {
        publications {
            mavenProject(MavenPublication) {
                from components.java
                groupId project.group
                artifactId varintName
                version project.version

                artifact sourceJar {
                    classifier "sources"
                }
            }
        }
    }

    bintray {
        user = project.hasProperty('bintrayUser') ? project.property('bintrayUser') : System.getenv('BINTRAY_USER')
        key = project.hasProperty('bintrayApiKey') ? project.property('bintrayApiKey') : System.getenv('BINTRAY_API_KEY')
        publications = ['mavenProject']
        pkg {
            repo = 'kotlinx'
            name = 'kotlinx.serialization.runtime'
            userOrg = 'kotlin'
            licenses = ['Apache-2.0']
            vcsUrl = 'https://github.com/Kotlin/kotlinx.serialization'
            websiteUrl = 'https://github.com/Kotlin/kotlinx.serialization'
            issueTrackerUrl = 'https://github.com/Kotlin/kotlinx.serialization/issues'

            githubRepo = 'Kotlin/kotlinx.serialization'
            version {
                name = project.version
            }
        }
    }
}